Add zsh/oh my zsh/w10k

zsh/.oh-my-zsh/plugins/aws/README.md

@@ -0,0 +1,38 @@
+# aws
+
+This plugin provides completion support for [awscli](https://docs.aws.amazon.com/cli/latest/reference/index.html)
+and a few utilities to manage AWS profiles and display them in the prompt.
+
+To use it, add `aws` to the plugins array in your zshrc file.
+
+```zsh
+plugins=(... aws)
+```
+
+## Plugin commands
+
+* `asp [<profile>]`: sets `$AWS_PROFILE` and `$AWS_DEFAULT_PROFILE` (legacy) to `<profile>`.
+  It also sets `$AWS_EB_PROFILE` to `<profile>` for the Elastic Beanstalk CLI.
+  Run `asp` without arguments to clear the profile.
+
+* `agp`: gets the current value of `$AWS_PROFILE`.
+
+* `aws_change_access_key`: changes the AWS access key of a profile.
+
+* `aws_profiles`: lists the available profiles in the  `$AWS_CONFIG_FILE` (default: `~/.aws/config`).
+  Used to provide completion for the `asp` function.
+
+## Plugin options
+
+* Set `SHOW_AWS_PROMPT=false` in your zshrc file if you want to prevent the plugin from modifying your RPROMPT.
+  Some themes might overwrite the value of RPROMPT instead of appending to it, so they'll need to be fixed to
+  see the AWS profile prompt.
+
+## Theme
+
+The plugin creates an `aws_prompt_info` function that you can use in your theme, which displays
+the current `$AWS_PROFILE`. It uses two variables to control how that is shown:
+
+- ZSH_THEME_AWS_PREFIX: sets the prefix of the AWS_PROFILE. Defaults to `<aws:`.
+
+- ZSH_THEME_AWS_SUFFIX: sets the suffix of the AWS_PROFILE. Defaults to `>`.

zsh/.oh-my-zsh/plugins/aws/aws.plugin.zsh

@@ -0,0 +1,96 @@
+function agp() {
+  echo $AWS_PROFILE
+}
+
+# AWS profile selection
+function asp() {
+  if [[ -z "$1" ]]; then
+    unset AWS_DEFAULT_PROFILE AWS_PROFILE AWS_EB_PROFILE
+    echo AWS profile cleared.
+    return
+  fi
+
+  local available_profiles=($(aws_profiles))
+  if [[ -z "${available_profiles[(r)$1]}" ]]; then
+    echo "${fg[red]}Profile '$1' not found in '${AWS_CONFIG_FILE:-$HOME/.aws/config}'" >&2
+    echo "Available profiles: ${(j:, :)available_profiles:-no profiles found}${reset_color}" >&2
+    return 1
+  fi
+
+  export AWS_DEFAULT_PROFILE=$1
+  export AWS_PROFILE=$1
+  export AWS_EB_PROFILE=$1
+}
+
+function aws_change_access_key() {
+  if [[ -z "$1" ]]; then
+    echo "usage: $0 <profile>"
+    return 1
+  fi
+
+  echo Insert the credentials when asked.
+  asp "$1" || return 1
+  aws iam create-access-key
+  aws configure --profile "$1"
+
+  echo You can now safely delete the old access key running \`aws iam delete-access-key --access-key-id ID\`
+  echo Your current keys are:
+  aws iam list-access-keys
+}
+
+function aws_profiles() {
+  [[ -r "${AWS_CONFIG_FILE:-$HOME/.aws/config}" ]] || return 1
+  grep '\[profile' "${AWS_CONFIG_FILE:-$HOME/.aws/config}"|sed -e 's/.*profile \([a-zA-Z0-9_\.-]*\).*/\1/'
+}
+
+function _aws_profiles() {
+  reply=($(aws_profiles))
+}
+compctl -K _aws_profiles asp aws_change_access_key
+
+# AWS prompt
+function aws_prompt_info() {
+  [[ -z $AWS_PROFILE ]] && return
+  echo "${ZSH_THEME_AWS_PREFIX:=<aws:}${AWS_PROFILE}${ZSH_THEME_AWS_SUFFIX:=>}"
+}
+
+if [ "$SHOW_AWS_PROMPT" != false ]; then
+  RPROMPT='$(aws_prompt_info)'"$RPROMPT"
+fi
+
+
+# Load awscli completions
+
+function _awscli-homebrew-installed() {
+  # check if Homebrew is installed
+  (( $+commands[brew] )) || return 1
+
+  # speculatively check default brew prefix
+  if [ -h /usr/local/opt/awscli ]; then
+    _brew_prefix=/usr/local/opt/awscli
+  else
+    # ok, it is not in the default prefix
+    # this call to brew is expensive (about 400 ms), so at least let's make it only once
+    _brew_prefix=$(brew --prefix awscli)
+  fi
+}
+
+# get aws_zsh_completer.sh location from $PATH
+_aws_zsh_completer_path="$commands[aws_zsh_completer.sh]"
+
+# otherwise check common locations
+if [[ -z $_aws_zsh_completer_path ]]; then
+  # Homebrew
+  if _awscli-homebrew-installed; then
+    _aws_zsh_completer_path=$_brew_prefix/libexec/bin/aws_zsh_completer.sh
+  # Ubuntu
+  elif [[ -e /usr/share/zsh/vendor-completions/_awscli ]]; then
+    _aws_zsh_completer_path=/usr/share/zsh/vendor-completions/_awscli
+  # RPM
+  else
+    _aws_zsh_completer_path=/usr/share/zsh/site-functions/aws_zsh_completer.sh
+  fi
+fi
+
+[[ -r $_aws_zsh_completer_path ]] && source $_aws_zsh_completer_path
+unset _aws_zsh_completer_path _brew_prefix